# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI="1"

inherit cmake-utils eutils git qt4

QT4_BUILT_WITH_USE_CHECK="dbus ssl"

EGIT_REPO_URI="git://git.dolezel.info/fatrat.git"
DESCRIPTION="Qt4-based download/upload manager"
HOMEPAGE="http://fatrat.dolezel.info/"
SRC_URI=""

LICENSE="GPL-2"
SLOT="0"
KEYWORDS=""
IUSE="bittorrent +curl -debug doc jabber nls webinterface"

RDEPEND="$(qt4_min_version 4.4.0)
    bittorrent? ( >=net-libs/rb_libtorrent-0.13_pre1683
                x11-libs/qt-webkit )
	curl? ( net-misc/curl )
    doc? ( x11-libs/qt-assistant )
    jabber? ( net-libs/gloox )
	webinterface? ( x11-libs/qt-webkit )"
DEPEND=">=dev-util/cmake-2.6.0
		${RDEPEND}"

S="${WORKDIR}/${PN}"

pkg_setup() {
	qt4_pkg_setup
	# this is a completely optional and NOT automagic dep
	# (it is dynamically loaded)
	if ! has_version dev-libs/geoip; then
		einfo "If you want the GeoIP support, then emerge dev-libs/geoip."
	fi
}

src_compile() {
	local myconf=""
	use debug && myconf="-DCMAKE_BUILD_TYPE=Debug"
	cmake . \
		-DCMAKE_INSTALL_PREFIX="/usr" \
		$(cmake-utils_use_with bittorrent BITTORRENT) \
		$(cmake-utils_use_with curl CURL) \
		$(cmake-utils_use_with doc DOCUMENTATION) \
		$(cmake-utils_use_with jabber JABBER) \
		$(cmake-utils_use_with nls NLS) \
		$(cmake-utils_use_with webinterface WEBINTERFACE) \
		${myconf} || die "cmake failed"
	emake || die "make failed"
}

src_install() {
	emake DESTDIR="${D}" install || die "make install failed"
}