# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils qt4 subversion

DESCRIPTION="The Qt eXTension library provides cross-platform utility classes to add functionality ontop of the Qt toolkit"
HOMEPAGE="http://libqxt.org/"
ESVN_REPO_URI="svn://libqxt.org/svn/libqxt/trunk"
LICENSE="CPL-1.0"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="debug fastcgi ssl"
DEPEND="|| ( >=x11-libs/qt-4.3:4
			( x11-libs/qt-gui:4
			x11-libs/qt-script:4
			x11-libs/qt-sql:4 )
		)
	ssl? ( >=dev-libs/openssl-0.9.8 )
	fastcgi? ( >=dev-libs/fcgi-2.4 )"
RDEPEND="${DEPEND}"

pkg_setup() {
	if has_version "=x11-libs/qt-4.3*"; then
		QT4_BUILT_WITH_USE_CHECK="png"  # png is on by default in qt-4.4
		QT4_OPTIONAL_BUILT_WITH_USE_CHECK="ssl"
	fi

	if use ssl; then
		if ! built_with_use "x11-libs/qt-core:4" ssl; then
			eerror "You have to build x11-libs/qt-core:4 with ssl."
			die "ssl support in qt-core disabled"
		fi
	fi
	qt4_pkg_setup
}

src_compile() {
	local myconf

	use debug && myconf="${myconf} -debug"
	use !ssl && myconf="${myconf} -nomake crypto"
	use !fastcgi && myconf="${myconf} -nomake web"

	./configure -prefix /usr ${myconf}

	make || die "make failed"  # emake mysteriously fails
}

src_install() {
	emake INSTALL_ROOT="${D}" install || die "emake install failed"
}