# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

DESCRIPTION="Crystallographic structure or charge density refinement"
HOMEPAGE="http://www.lcm3b.uhp-nancy.fr/lcm3b/Logiciels-labo/MoPro.htm"
SRC_URI="bin-Linux.zip
	Doc-MoPro.zip
	LibMoPro.zip"
RESTRICT="fetch"
LICENSE="free-noncomm"
SLOT="0"
KEYWORDS="~x86"
IUSE=""
RDEPEND=""
DEPEND="${RDEPEND}"
S="${WORKDIR}/MoPro"

pkg_nofetch() {
	einfo "Fill out the form at http://www.emqc.uhp-nancy.fr/mopro-formulaire.html"
	einfo "and place these files:"
	einfo "${A}"
	einfo "in ${DISTDIR}."
}

src_unpack() {
	unpack ${A}

	# Fix locations
	ebegin "Updating default locations"
	sed -i \
		-e "s:~/MoPro/Example-small-molecule:~:g" \
		-e "s:~/MoPro/LibMoPro/mopro.tab:${ROOT}usr/share/mopro/mopro.tab:g" \
		-e "s:~/MoPro/LibMoPro/WAVEF:${ROOT}usr/share/mopro/WAVEF:g" \
		-e "s:/usr/bin/kghostview:${ROOT}usr/bin/evince:g" \
		"${S}"/bin*/*.ini
	# Delete whitespace-only lines
	sed -i \
		-e "/^[[:space:]]*$/d" \
		"${S}"/bin*/*.ini
	# Tag on default .dat location
	echo "FILE  ANOM  ${ROOT}usr/share/mopro/asf_Kissel.dat" \
		>> "${S}"/bin*/*.ini
	eend 0
}

src_install() {
	# Binaries
	pushd "${S}"/bin* > /dev/null
	newbin cubesliceLinux.exe cubeslice
	newbin Flat-Solvent-Linux59.exe Flat-Solvent
	newbin Import2MoPro-Linux-64b.exe Import2MoPro
	newbin MoPro-Linux-66b.exe MoPro
	newbin VMoPro-Linux-65f.exe VMoPro
	popd > /dev/null

	# Default config file
	insinto /usr/bin
	doins "${S}"/bin*/*.ini

	# Data
	insinto /usr/share/mopro
	doins "${S}"/Lib*/asf_Kissel.dat
	doins "${S}"/Lib*/mopro.tab
	doins "${S}"/Lib*/WAVEF

	# Docs
	dohtml "${S}"/*.htm
}