# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EBZR_BRANCH="trunk"
EBZR_REPO_URI="https://code.launchpad.net/~awn-core/awn/"
inherit autotools bzr gnome2

DESCRIPTION="Avant Window Navgator is a dock-like bar that keeps track of open windows."
HOMEPAGE="https://launchpad.net/awn-extras/"
SRC_URI=""

LICENSE="GPL-2 LGPL-2.1"
SLOT="0"
KEYWORDS=""
IUSE="doc gconf gnome vala xfce"

COMMON_DEPS="
	x11-libs/gtk+
	x11-libs/libwnck
	gconf? (
		gnome-base/gconf
	)
	gnome? (
		gnome-base/gnome-desktop
		gnome-base/gnome-vfs
		gnome-base/libgnome
	)
	xfce? ( xfce-base/thunar )
	!gnome? (
		!xfce? ( >=dev-libs/glib-2.15.0 )
	)"
DEPEND="${COMMON_DEPS}
	dev-util/gtk-doc"
RDEPEND="${COMMON_DEPS}
	dev-python/pyxdg
	vala? ( >=dev-lang/vala-0.3.4 )"

src_unpack() {
	bzr_src_unpack
	gtkdocize || die "gtkdocsize failed"
	intltoolize --copy --force || die "intltoolize failed"
	eautoreconf || die "eautoreconf failed"
}

src_compile() {
	local myconf

	# These are alternatives so it won't work with use_with
	if use gnome; then
		myconf="--with-desktop=gnome"
	elif use xfce; then
		myconf="--with-desktop=xfce4"
	else
		myconf="--with-desktop=agnostic"
	fi

	econf ${myconf} \
		$(use_enable doc gtk-doc) \
		$(use_with gconf) \
		$(use_with vala) \
		|| die "econf failed"

	emake || die "emake failed"
}

pkg_postinst() {
	gnome2_pkg_postinst

	ewarn "DO NOT report bugs to Gentoo's bugzilla"
	elog "Please report all bugs to #gentoo-desktop-effects and if"
	elog "they are upstream bugs to https://bugs.launchpad.net/awn/"
}