# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

MY_PN="${PN/compiz-fusion-}"

inherit autotools git

EGIT_REPO_URI="git://anongit.compiz-fusion.org/fusion/${MY_PN}"

DESCRIPTION="Compiz Fusion Window Manager Plugins (git)"
HOMEPAGE="http://compiz-fusion.org"
SRC_URI=""

LICENSE="GPL-2"
SLOT="0"
KEYWORDS=""
IUSE="gnome"

RDEPEND="
	>=gnome-base/librsvg-2.14.0
	media-libs/jpeg
	~x11-wm/compiz-${PV}
	~x11-libs/compiz-bcop-${PV}
"

DEPEND="${RDEPEND}
	>=dev-util/intltool-0.35
	>=dev-util/pkgconfig-0.19
	>=sys-devel/gettext-0.15
	gnome? ( gnome-base/gconf )
"

S="${WORKDIR}/${MY_PN}"

pkg_setup() {
	if ! built_with_use x11-libs/cairo glitz ; then
		einfo "Please rebuild cairo with USE=\"glitz\""
		die "x11-libs/cairo missing glitz support"
	fi
}

src_unpack() {
	git_src_unpack
	use gnome || epatch "${FILESDIR}"/${PN}-no-gconf.patch

	intltoolize --automake --copy --force || die "intloolize failed"
	eautoreconf || die "eautoreconf failed"
}

src_compile() {
	econf \
		$(use_enable gnome gconf) \
		|| die "econf failed"
	emake || die "emake failed"
}

src_install() {
	emake DESTDIR="${D}" install || die "emake install failed"
}

pkg_postinst() {
	ewarn "DO NOT report bugs to Gentoo's bugzilla"
	einfo "Please report all bugs to #gentoo-desktop-effects"
	einfo "Thank you on behalf of the Gentoo Desktop-Effects team"
}