# Copyright 1999-2005 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/games-arcade/tecnoballz/tecnoballz-0.91.ebuild,v 1.1 2005/12/27 12:10:32 egore Exp $

inherit games

DESCRIPTION="A Brick Breaker with 50 levels of game and 11 special levels"
HOMEPAGE="http://linux.tlk.fr/games/TecnoballZ/"
SRC_URI="http://linux.tlk.fr/games/TecnoballZ/download/${P}.tgz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="x86"
IUSE=""

DEPEND="virtual/libc
	>=media-libs/libsdl-1.2
	media-libs/libmikmod
	media-libs/sdl-mixer"

src_unpack() {
	unpack ${A}
	cd "${S}"
	sed -i \
		-e '/^CC/d; /^CXX/d; /^PREFIX/d' \
		-e "s:^EXEDIR.*=:& ${GAMES_BINDIR}:" \
		-e "s:^MANDIR.*=:& /usr/share/man:" \
		-e "s:^DATADIR.*=:& ${GAMES_DATADIR}/${PN}:" \
		-e "s:^SCOrEDIR.*=:& ${GAMES_STATDIR}:" \
		src/Makefile \
		|| die "sed failed"
	sed -i \
		-e "s:/var/lib/games/tecnoballz.hi:${GAMES_STATEDIR}/tecnoballz.hi:" \
		-e "s:/usr/share/games/tecnoballz:${GAMES_DATADIR}/tecnoballz:" \
		src/ressources.cc \
		|| die "sed failed"
	find src/TecnoballZ/ -type d -name .xvpics -exec rm -rf \{\} \;

	epatch ${FILESDIR}/${P}-gcc41.patch
	epatch ${FILESDIR}/${P}-build.patch
}

src_compile() {
	emake -C src || die "emake failed"
}

src_install() {
	dogamesbin src/tecnoballz || die "dogamesbin failed"
	newman man/tecnoballz.1 tecnoballz.6
	dodoc AUTHORS CHANGES README

	dodir "${GAMES_DATADIR}/tecnoballz"
	cp -r src/TecnoballZ "${D}${GAMES_DATADIR}/tecnoballz" \
		|| die "cp failed"

	insinto "${GAMES_STATEDIR}"
	insopts -m 660
	doins tecnoballz.hi || die "doins failed"
	prepgamesdirs
}