# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-fonts/frakturx/frakturx-20070103.ebuild,v 1.1 2007/04/18 19:28:35 ulm Exp $

inherit latex-package

DESCRIPTION="Collection of fraktur fonts for LaTeX"
HOMEPAGE="http://www.gaehrken.de/fraktur/"
#SRC_URI="http://www.gaehrken.de/fraktur/base.zip
#	http://www.gaehrken.de/fraktur/tfrak.zip
#	http://www.gaehrken.de/fraktur/obibel.zip
#	http://www.gaehrken.de/fraktur/odedruck.zip
#	http://www.gaehrken.de/fraktur/odeschmk.zip
#	http://www.gaehrken.de/fraktur/oweissfr.zip
#	http://www.gaehrken.de/fraktur/oweissgo.zip
#	http://www.gaehrken.de/fraktur/talteswab.zip
#	http://www.gaehrken.de/fraktur/tbrtkpf.zip
#	http://www.gaehrken.de/fraktur/tkngsbg.zip
#	http://www.gaehrken.de/fraktur/twieynk.zip
#	http://www.gaehrken.de/fraktur/twieyvig.zip
#	http://www.gaehrken.de/fraktur/tzentenar.zip"
# All above-mentioned archives have been repackaged into one file:
SRC_URI="http://wwwa1.kph.uni-mainz.de/users/ulm/distfiles/${P}.tar.gz"

LICENSE="LPPL-1.2 free-noncomm"
SLOT="0"
KEYWORDS="~x86"
IUSE=""

src_install() {
	dodir ${TEXMF}
	tar -cf - --exclude="._*" fonts/{tfm,vf,type1,enc} tex dvips/base |
		tar -C "${D}"${TEXMF} -xf - || die
	dodir /usr/share/doc/${PF}
	tar -C doc/fonts/fraktur -cf - --exclude="._*" . |
		tar -C "${D}"/usr/share/doc/${PF} -xf - || die

	dodir ${TEXMF}/fonts/map/dvips/misc
	sed -e '$s/$/\n/' fonts/map/dvips/*.map \
		>"${D}"${TEXMF}/fonts/map/dvips/misc/frakturx.map
	dodir ${TEXMF}/dvips/misc
	dosym {../../fonts/map,${TEXMF}}/dvips/misc/frakturx.map
	dodir /etc/texmf/updmap.d
	echo 'Map frakturx.map' >"${D}"/etc/texmf/updmap.d/01frakturx.cfg
}

pkg_postinst() {
	local f=${ROOT}${TEXMF}/web2c/updmap.cfg
	if ! latex-package_has_tetex_3 && [ -f ${f} ]; then
		grep -q '^Map frakturx\.map' ${f} || echo 'Map frakturx.map' >>${f}
		updmap
	fi
	latex-package_pkg_postinst
}

pkg_postrm() {
	local f=${ROOT}${TEXMF}/web2c/updmap.cfg
	if ! latex-package_has_tetex_3 && [ -f ${f} ]; then
		[ ! -f ${ROOT}${TEXMF}/fonts/map/dvips/misc/frakturx.map ] \
			&& grep -q '^Map frakturx\.map' ${f} \
			&& sed -i -e '/^Map frakturx\.map/d' ${f}
		updmap
	fi
	latex-package_pkg_postrm
}