# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

REV=${PV/*_pre}

inherit flag-o-matic subversion autotools

DESCRIPTION="interactive process viewer"
HOMEPAGE="http://htop.sourceforge.net"
ESVN_REPO_URI="https://htop.svn.sourceforge.net/svnroot/htop/trunk@${REV}"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
IUSE="debug openvz vserver"

DEPEND="sys-libs/ncurses
	vserver? ( sys-cluster/util-vserver )"

pkg_setup() {
	if use elibc_FreeBSD ; then
		elog
		elog "htop needs /proc mounted to work, to mount it type"
		elog "mount -t linprocfs none /proc"
		elog "or uncomment the example in /etc/fstab"
		elog
	fi
}

src_unpack() {
	subversion_src_unpack
	epatch "${FILESDIR}"/${PN}-0.7.1-vserver.patch
	eautoreconf
}

src_compile() {
	useq debug && append-flags -O -ggdb -DDEBUG
	econf $(use_enable openvz) $(use_enable vserver) || die "configure failed"
	emake || die "make failed"
}

src_install() {
	emake DESTDIR="${D}" install || die "make install failed"
	dodoc README ChangeLog TODO
	use vserver && dosbin "${FILESDIR}"/vhtop
}